@echo off
rem
rem This script creates local club rating lists.
rem

rem Check input requirements
if X%1==X goto ARGS
if not X%2==X goto ARGS
goto READYGO

:ARGS
echo The following command line argument is expected:
echo    1. base ratings file
echo For example,
echo    %0 base 
echo.
goto STOPBAT

:READYGO
rem Verify existence of base ratings file.
if exist %1.TDE goto RG1
echo %1.TDE not found
goto STOPBAT

:RG1
rem Erase any previous efforts and temporary files
if exist RATSLRCW.TXT erase RATSLRCW.TXT
if exist RATSLNCW.TXT erase RATSLNCW.TXT
if exist RATSLRWP.TXT erase RATSLRWP.TXT
if exist RATSLNWP.TXT erase RATSLNWP.TXT
if exist RATSLRWEB.HTM erase RATSLRWEB.HTM
if exist RATSLNWEB.HTM erase RATSLNWEB.HTM
if exist *.LOG erase *.LOG

echo Processing ...

rem Write ratings list in constant width font format.
arexe30 areportp %1 /tag=name /tag=rating /tag=id /out=RATSLNCW
if errorlevel 1 goto STOPBAT
arexe30 areportp %1 /tag=rating /tag=name /tag=id /out=RATSLRCW
if errorlevel 1 goto STOPBAT

rem Write ratings list with a tab before each field.
arexe30 areportp %1 /tag=name /tag=rating /tag=id /wp /out=RATSLNWP
if errorlevel 1 goto STOPBAT
arexe30 areportp %1 /tag=rating /tag=name /tag=id /wp /out=RATSLRWP
if errorlevel 1 goto STOPBAT

rem Write ratings list in HTML.
arexe30 areportp %1 /tag=name /tag=rating /tag=id /html /out=RATSLNWEB
if errorlevel 1 goto STOPBAT
arexe30 areportp %1 /tag=rating /tag=name /tag=id /html /out=RATSLRWEB
if errorlevel 1 goto STOPBAT
rename RATSLNWEB.TXT RATSLNWEB.HTM
rename RATSLRWEB.TXT RATSLRWEB.HTM

rem
rem Clean up.
rem

rem Erase temporary files
erase *.LOG

rem
rem Tell the user what was output.
rem

echo Look for the following output files:
echo    RATSLNCW.TXT   - ratings list, name order, assuming constant width font
echo    RATSLRCW.TXT   - ratings list, rating order, assuming constant width font
echo    RATSLNWP.TXT   - ratings list, name order, with tabs for word processor
echo    RATSLRWP.TXT   - ratings list, rating order, with tabs for word processor
echo    RATSLNWEB.HTM  - ratings list, name order, for web browser
echo    RATSLRWEB.HTM  - ratings list, rating order, for web browser
echo    

goto DONE

:STOPBAT
echo Script execution stopped due to error.

:DONE